1. LTspice
  2. Теми

Diode breakdown region

 

Hello,
I try to look a bit more in detail at the breakdown region of the diodes, and for that, I am currently using the hand-made model depicted in the Diode_Model_Reverse.asc file uploaded to the Temp folder. It is very basic.
 
What I notice is that the reverse current gradually increases from below 10pA @ 5V to about 100pA @ 99V, before breakdown occurs. I would like to change the characteristic so that current stays at values closer to 0, before the breakdown occurs. So something like 10pA @ 99V.
 
I would be very grateful if you could point me to some meaningful resources describing the extended diode model in this region. Whereas I am able to find some info concerning the BV and IBV parameters, I am completely lacking a good understanding on the effect of the nbv, nbvl, ibvl parameters, and I am also having difficulties in finding a good description of those. Despite that, I have tried changing these parameters (as well as the Is parameter, as a matter of fact) without much impact on the current through the diode when reverse biased at 99V. It seems to be stuck at 100pA @99V no matter what.
 
Regards,
Cristian
 

Well, I have to ammend a bit what I wrote. The Is parameter does seem to influence behaviour in this regain, but only if I increase it. I ntat case, the current at 99V reverse voltage can get bigger than the 100pA. But never lower, even if I make Is much smaller than its default 1e-14 value.
 
Змінено

Berceanu Cristian wrote:
What I notice is that the reverse current gradually increases from below 10pA @ 5V to about 100pA @ 99V, before breakdown occurs. I would like to change the characteristic so that current stays at values closer to 0, before the breakdown occurs. So something like 10pA @ 99V.
The current that you see is unrelated to the diode's breakdown.  If you remove the breakdown parameters, you get the same simulated current.
 
(1)  All diodes conduct a little revers current when not in or near breakdown.  It is primarily determined by the IS parameter, the reverse saturation current.  Its default value is l1e-14 (oops!) 1e-14 A (0.01 pA).
 
(2)  GMIN.  It is one of SPICE's global parameters.  SPICE places a resistance across every PN junction, whose conductance equals GMIN.  THAT is what you're seeing.  The default GMIN is 1e=12, equivalent to a 1 Tohm resistor.
 
Add this to your simulation:
    .options GMIN=1e-18
and run it again.
 
Andy
 
 

That is true and... it worked! 
 
Thanks.
 

Hi Cristian, 
I don't mean to question your purpose, but it's difficult to draw any reliable conclusions from LTSpice at breakdown limits, for ordinary diodes and transistors.  These parts are simulation-accurate only within their SOA, as a general rule.  The actual breakdown voltage of a part specified at 100Vminimum  is usually a wide tolerance, it depends on surface contamination, guard-ring line roughness, all sorts of sub-parameters that are not individually specified. 
The easiest approach is to keep within SOA.  For "gross" overload, like lightning or ESD, bipolar parts avalanche into a plasma, an "n"-terminal short-circuit - and normally this does not damage the part as long as it is kept within thermal limits - which can be 350'C - 400'C for short periods. 
If you really need to know what happens in breakdown, then maybe avalanche transistors or diodes would be a better start for simulation, as the relevant parameters are controlled and the models are valid at these extreme conditions. 
In the broadest terms, it's a "solve or avoid" type of problem, probably - I'm guessing here.   
I'd stick to "avoid" - as diodes or series diodes are available up to many kV. 
If you have poorly-specified Vmax, could be umpteen kV, then simple ZnO varistors, and stray inductance, or GDT arrestors, are the thing. 
 
 
 

I think my example with diodes will be useful to you and only you.
The effect of spice parameters on the reverse current of the diode.
See file ExampleDiode.zip in TEMP folder.
 
Bordodynov.
 

Thank you all.
Yes, I am aware of the limits of usefulness of the simulation near the breakdown voltage. I am not evaluating the diode itself, but I just need a load with an approximate behaviour for a supply circuit I am fiddling with (a high voltage charge pump for APDs).
The behaviour I highlighted in my original post would not have a tremendous impact on my simulation, I was just intrigued by not understanding why it happens.
 
Regards,
Cristian 
 

See example APD
.Subckt S6045_1 P dm dp k=0.5 ids=100p idg=100f
.param C0=10.8p rs=10
r p 0 1gig
* k- koeff A/Wt
g dm 8 P 0 {k}
Rs 12 dp {rs}
* C ot V
c dm 120 {C0}
va 120 12 0
bc dm 12 i=i(va)*(TABLE(v(dm,12), 0,1 , 30,0.4 , 50,0.3 , 65,0.2 , 100,0.13 , 150,0.12 , 200,0.12)-1)
* M ot V
B3 M 0 v=TABLE(v(dm,12), 0,1 , 120,2., 140,2.5, 160,4 , 170,5.5, 180,8 , 200,15 , 220,40 , 230,200 , 240,10000)
* F ot M
B4 F 0 v=TABLE(v(M), 1,1 , 5,1.26 , 10,1.6 , 40,3 , 100,4, 1000,10)
*
D1 8 dm diode
iidg dm 8 {idg}
iids dm 12 {ids}
.model diode D is=.0001f tt=10u
VAm2 8 13 0
VAm3 13 12 0
BM dm 13 i=i(vam2)*(v(M)-1)
*noise
Q1 0 9 10 npn
Q2 0 9 14 pnp
VAm4 0 9 0
B1 10 14 i=2*(i(vam3)*v(F)+{ids})
B2 dm 12 i=i(vam4)
*
.model npn npn bf=1 is=0.01f
.model pnp pnp bf=1 is=0.01f
.ends S6045_1
.Subckt S8890-05 P dm dp k=0.5 ids=100p idg=2p
.param C0=10.8p rs=10
r p 0 1gig
* k- koeff A/Wt
g dm 8 P 0 {k}
Rs 12 dp {rs}
* C ot V
c dm 120 {C0}
va 120 12 0
bc dm 12 i=i(va)*(TABLE(v(dm,12), 0,1 , 65,0.4 , 100,0.2 , 150,0.05 , 200,0.05)-1)
* M ot V
B3 M 0 v=TABLE(v(dm,12), 0,1 , 120,1.5, 200,10 , 300,20 , 400,100 , 420,2000, 422,10000)
* F ot M
B4 F 0 v=TABLE(v(M), 1,1 , 5,1.26 , 10,1.6 , 40,3 , 100,4, 1000,10)
*
D1 8 dm diode
iidg dm 8 {idg}
iids dm 12 {ids}
.model diode D is=.0001f tt=10u
VAm2 8 13 0
VAm3 13 12 0
BM dm 13 i=i(vam2)*(v(M)-1)
*noise
Q1 0 9 10 npn
Q2 0 9 14 pnp
VAm4 0 9 0
B1 10 14 i=2*(i(vam3)*v(F)+{ids})
B2 dm 12 i=i(vam4)
*
.model npn npn bf=1 is=0.01f
.model pnp pnp bf=1 is=0.01f
.ends S8890-05
 
 

Thanks!

1 - 9 з 9